program TestProg;
{$APPTYPE CONSOLE}
uses
  Windows, SysUtils;

  function SysErrorMessage(ErrorCode: Integer): string;
  begin
    Result := SysUtils.SysErrorMessage(ErrorCode);
    ANSItoOEM(PChar(Result), PChar(Result));
    If Result <> '' Then
      Result := Format('%s (Error %d)', [Result, ErrorCode]);
  end;

Type
  TTokenPrivileges = record
    PrivilegeCount: DWORD;
    Privileges: array[0..1] of TLUIDAndAttributes;
  end;

Var
  pHndl: THandle;
  aSD: PSecurityDescriptor;
  aSize: DWord;
  hToken: THandle;
  tkp: TTokenPrivileges;
begin
  hToken := 0;
  Try
    ZeroMemory(@tkp, SizeOf(tkp));
    //чтобы потестить  только с SeSecurityPrivilege, выставьте здесь единичку вместо двойки.
    tkp.PrivilegeCount := 2;
    tkp.Privileges[0].Attributes := SE_PRIVILEGE_ENABLED;
    tkp.Privileges[1].Attributes := SE_PRIVILEGE_ENABLED;

    If Not (//Выставляем привилегии для процесса
      OpenProcessToken(GetCurrentProcess, TOKEN_ADJUST_PRIVILEGES Or TOKEN_QUERY, hToken) And
      LookupPrivilegeValue(Nil, 'SeSecurityPrivilege', tkp.Privileges[0].Luid) And
      LookupPrivilegeValue(Nil, 'SeDebugPrivilege', tkp.Privileges[1].Luid) And
      AdjustTokenPrivileges(hToken, False, PTokenPrivileges(@tkp)^, 0, Nil, PDWORD(Nil)^))
    Then Begin
      WriteLn(SysErrorMessage(GetLastError));
      Exit;
    End;

    //Открываем процесс с требуемым уровнем доступа
    pHndl := OpenProcess(MAXIMUM_ALLOWED Or ACCESS_SYSTEM_SECURITY, False, GetCurrentProcessID);
    If pHndl = 0 Then Begin
      WriteLn(SysErrorMessage(GetLastError));
      Exit;
    End; // Прикольно, что здесь всё нормально, OS выдаёт дескриптор процесса с этим уровнем доступа!

    Try
      aSD := Nil; //   VVV    А вот здесь ненормально - возвращает false и говорит, что в доступе отказано!
      GetKernelObjectSecurity(pHndl, SACL_SECURITY_INFORMATION, aSD, 0, aSize);
      If GetLastError <> ERROR_INSUFFICIENT_BUFFER Then
      Begin
        WriteLn(SysErrorMessage(GetLastError));
        Exit;
      End;
      GetMem(aSD, aSize);
      Try
        If Not GetKernelObjectSecurity(pHndl, SACL_SECURITY_INFORMATION, aSD, aSize, aSize) Then
        Begin
          WriteLn(SysErrorMessage(GetLastError));
          Exit;
        End;
      Finally
        FreeMem(aSD);
      End;
    Finally
      CloseHandle(pHndl);
    End;
    WriteLn('Success!');
  Finally
    If hToken <> 0 Then CloseHandle(hToken);
    Write('Press Enter to continue...');
    ReadLn;
  End;
end.