@echo off

if "%1" == "/install" goto install
if "%1" == "/uninstall" goto uninstall
if "%1" == "/deinstall" goto uninstall
if "%1" == "/start" goto start
if "%1" == "/stop" goto stop
if "%1" == "/runkeeper" goto loop
goto usage

:loop
ping -w 1000 -n 5 127.0.0.1 >nul 2>nul

:check
ping -n 1 www.yandex.ru >nul 2>nul
if not errorlevel 1 goto loop

echo yandex ping failed, try google

ping -n 1 www.google.com >nul 2>nul
if not errorlevel 1 goto loop

echo google ping failed, try leo

ping -n 1 leo.yuriev.ru >nul 2>nul
if not errorlevel 1 goto loop

echo leo ping failed, connection broken, redial

:redial
rasdial %2 /disconnect >nul 2>nul
rasdial %2 %3 %4
if errorlevel 1 goto redial

goto check

:usage
echo Usage:
echo 	install service -	%0 /install dialup-entry-name [login [password]]
echo 	remove service	-	%0 /uninstall
echo 	start service	-	%0 /start
echo 	stop service	-	%0 /stop
echo 	run keeper	-	%0 /runkeeper  dialup-entry-name [login [password]]
exit 1

:start
sc.exe start AppToService_lyDialupKeeper
exit 0

:stop
sc.exe stop AppToService_lyDialupKeeper
exit 0

:install
echo on
"%ProgramFiles%\Basta Computing\AppToService\AppToService.exe" /Install "%ComSpec%" /AbsName:lyDialupKeeper /Arguments:"/Q /C %0 /runkeeper %2 %3 %4" /Closing:2 /DependOn:RasMan/RemoteAccess/Dnscache /Interact:0 /Startup:A
sc.exe config AppToService_lyDialupKeeper DisplayName= "LY's dialup or VPN connection keeper & redialer"
exit 0

:uninstall
sc.exe stop AppToService_lyDialupKeeper
sc.exe delete AppToService_lyDialupKeeper
exit 0